명령행 결과를 윈도(메모)로 나타나게 하는 방법입니다.
즉, ipconfig의 결과를 Memo로 보이게 하는 방법입니다.

파이어버드의 백업(gbak.exe)을 윈도로 보여줄 때 사용하고 있는데 다른 용도로도 활용이 가능할 것 같습니다....


unit Unit4;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.ExtCtrls;

type
  TArg<T> = reference to procedure(const Arg: T);

  TForm4 = class(TForm)
    Memo: TMemo;
    Panel1: TPanel;
    Label1: TLabel;
    edCommand: TEdit;
    btnExecCmd: TButton;
    procedure btnExecCmdClick(Sender: TObject);
    procedure edCommandKeyPress(Sender: TObject; var Key: Char);
  private
    procedure CaptureConsoleOutput(const ACommand: String;
      CallBack: TArg<PAnsiChar>);
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form4: TForm4;

implementation

{$R *.dfm}

procedure TForm4.CaptureConsoleOutput(const ACommand: String; CallBack: TArg<PAnsiChar>);
const
  CReadBuffer = 2400;
var
   saSecurity: TSecurityAttributes;
   hRead: THandle;
   hWrite: THandle;
   suiStartup: TStartupInfo;
   piProcess: TProcessInformation;
   pBuffer: array [0..CReadBuffer] of AnsiChar;
   dBuffer: array [0..CReadBuffer] of AnsiChar;
   dRead: DWORD;
   dRunning: DWORD;
   dAvailable: DWORD;
 begin
   saSecurity.nLength := SizeOf(TSecurityAttributes);
   saSecurity.bInheritHandle := true;
   saSecurity.lpSecurityDescriptor := nil;
   if CreatePipe(hRead, hWrite, @saSecurity, 0) then
     try
       FillChar(suiStartup, SizeOf(TStartupInfo), #0);
       suiStartup.cb := SizeOf(TStartupInfo);
       suiStartup.hStdInput := hRead;
       suiStartup.hStdOutput := hWrite;
       suiStartup.hStdError := hWrite;
       suiStartup.dwFlags := STARTF_USESTDHANDLES or STARTF_USESHOWWINDOW;
       suiStartup.wShowWindow := SW_HIDE;
       if CreateProcess(nil, PChar(ACommand), @saSecurity, @saSecurity, true, NORMAL_PRIORITY_CLASS, nil, nil, suiStartup,
         piProcess) then
         try
           repeat
             dRunning := WaitForSingleObject(piProcess.hProcess, 100);
             PeekNamedPipe(hRead, nil, 0, nil, @dAvailable, nil);
             if (dAvailable > 0) then
               repeat
                 dRead := 0;
                 ReadFile(hRead, pBuffer[0], CReadBuffer, dRead, nil);
                 pBuffer[dRead] := #0;
                 OemToCharA(pBuffer, dBuffer);
                 CallBack(dBuffer);
               until (dRead < CReadBuffer);
             Application.ProcessMessages;
           until (dRunning <> WAIT_TIMEOUT);
         finally
             CloseHandle(piProcess.hProcess);
             CloseHandle(piProcess.hThread);
         end;
     finally
         CloseHandle(hRead);
         CloseHandle(hWrite);
     end;
end;

procedure TForm4.edCommandKeyPress(Sender: TObject; var Key: Char);
begin
    if Key = #13 then
    begin
        btnExecCmd.SetFocus;
        Key := #0;
    end;
end;

procedure TForm4.btnExecCmdClick(Sender: TObject);
begin
    Memo.Lines.Clear;

    CaptureConsoleOutput(edCommand.Text,
        procedure(const Line: PAnsiChar)
        begin
            Memo.Lines.Add(String(Line));
        end);
end;

end.


// 소란코더님의 지적에 따라 소스를 다시 올렸습니다.