프로젝트에 그리드 속성을 일괄적용하기 위해 함수로 정리했습니다.
필터문자 퍼센트, 언더바를 *, ?로 지정했습니다.
폼생성 부분에서 xSetGrid(그리드명)하시면 모든 테이블뷰를 설정합니다(한방에)

procedure xSetGrid(const pGrid: TcxGrid;
                          const pFilterCombo: Boolean = True; // 필터콤보 적용여부
                          const pFilterRow: Boolean = False); // 필터입력 적용여부
// 그리드 사전설정값을 프로젝트 일률적으로 설정
  procedure SetTableView(const pGridTV: TcxGridTableView);
  const
    iHeaderHeight = 22; 
    iDataRowHeight = 22; // 기본값 0(17)
  var
    i: Integer;
  begin
    with pGridTV do begin
      BeginUpdate;
      with DataController do begin
        Filter.PercentWildcard := '*';
        Filter.UnderscoreWildcard := '?';
      end;
      FilterBox.Visible := fvNever;
      Filtering.ColumnPopup.MaxDropDownItemCount := 31;
      with FilterRow do begin
        ApplyChanges := fracImmediately;
        SeparatorWidth := 2;

        if False { pFilterRow } then begin
          Visible := not DataController.IsDetailMode;
        end
        else Visible := False;
      end;

      if pFilterCombo then begin
        OptionsCustomize.ColumnFiltering := not DataController.IsDetailMode;
      end
      else OptionsCustomize.ColumnFiltering := False;

      if pGridTV is TcxGridBandedTableView then begin
        with TcxGridBandedTableView(pGridTV) do begin
          OptionsView.BandHeaderHeight := iHeaderHeight;
          OptionsCustomize.ColumnVertSizing := False;
        end;
      end;

      OptionsSelection.CellSelect := False; // 셀선택여부

      with OptionsView do begin
        DataRowHeight := iDataRowHeight;
        HeaderHeight := iHeaderHeight;
        GridLineColor := $00E4E4E4;
        GridLines := cxGraphics.glBoth; // glNone
        GroupByBox := False;
        GroupRowHeight := iHeaderHeight;
        GroupSummaryLayout := gslAlignWithColumns;
        HeaderFilterButtonShowMode := fbmButton;
        ShowColumnFilterButtons := sfbAlways; // sfbWhenSelected;
      end;

      for i := 0 to ColumnCount - 1 do begin
        if OptionsView.Footer then begin
          Columns[i].FooterAlignmentHorz := taRightJustify;
        end;

        Columns[i].HeaderAlignmentHorz := taCenter;
        Columns[i].HeaderAlignmentVert := cxClasses.vaCenter; // Default

        if (Columns[i].Properties = nil) then begin
          Columns[i].PropertiesClass := TcxLabelProperties;
        end;

        if (Columns[i].PropertiesClass = TcxLabelProperties) then begin
          Columns[i].Properties.Alignment.Vert := taVCenter;
          Columns[i].Properties.Alignment.Horz := taLeftJustify;
        end
        else if (Columns[i].PropertiesClass = TcxTextEditProperties) then begin
          Columns[i].Properties.Alignment.Vert := taVCenter; // Default
        end
        else if (Columns[i].PropertiesClass = TcxButtonEditProperties) then begin
          Columns[i].Options.Filtering := False;
          Columns[i].Options.ShowEditButtons := isebAlways;
          Columns[i].Options.Sorting := False;
        end
        else if (Columns[i].PropertiesClass = TcxImageComboBoxProperties) then begin
          Columns[i].Properties.Alignment.Horz := taCenter;
          TcxImageComboBoxProperties(Columns[i].Properties).DropDownRows := 31;
          TcxImageComboBoxProperties(Columns[i].Properties).ImmediatePost := True;
        end
        else if (Columns[i].PropertiesClass = TcxCheckBoxProperties) then begin
          TcxCheckBoxProperties(Columns[i].Properties).ImmediatePost := True;
          TcxCheckBoxProperties(Columns[i].Properties).NullStyle := nssUnchecked;
          TcxCheckBoxProperties(Columns[i].Properties).ValueChecked := True;
          TcxCheckBoxProperties(Columns[i].Properties).ValueUnchecked := False;
          with Columns[i], Options do begin
            HeaderAlignmentHorz := taCenter;
          end
        end
        else if (Columns[i].PropertiesClass = TcxDateEditProperties) then begin // cxCalendar
          TcxDateEditProperties(Columns[i].Properties).ImmediatePost := True;
          TcxDateEditProperties(Columns[i].Properties).InputKind := ikRegExpr;
          if Columns[i].Tag = 0 then begin
            TcxDateEditProperties(Columns[i].Properties).DateButtons := [btnToday];
          end;
        end;
      end;
      EndUpdate;
    end;

  end;

var i: Integer;
begin
    with pGrid do begin
        BevelEdges := [beTop, beBottom];
        BevelInner := bvRaised;
        BevelKind := bkFlat;
        BevelOuter := bvNone;
        BorderStyle := cxControls.cxcbsNone;

        for i := 0 to ViewCount - 1 do begin
            if (views[i] is TcxGridTableView) or
                (views[i] is TcxGridBandedTableView) then begin
                SetTableView(TcxGridTableView(Views[i]));
            end;
        end;
    end;
end;