자바의 Toast를 파이어멍키로 만들어 봤습니다...
자바의 Toast에 빗대어 Bread라고 했는데 쓰실 분들은 마음대로 Naming해서 쓰시기 바랍니다....
그리고 이를 이용해 뒤로 버튼을 두 번 눌러 앱을 종료하는 방법입니다...
(초 단위가 아닌 Millisecond 단위로 적용.)

// 사용 방법입니다..

unit Unit1;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.VirtualKeyboard, FMX.Platform,
  System.DateUtils, FMX.Controls.Presentation, FMX.StdCtrls;

type
  TForm1 = class(TForm)
    Label1: TLabel;
    procedure FormKeyUp(Sender: TObject; var Key: Word; var KeyChar: Char;  Shift: TShiftState);
    procedure FormCreate(Sender: TObject);
  private
     // 뒤로 버튼이 눌려 졌는지를 체크...
      HardwareBackClickCheckFlag: Boolean;
     // 버튼이 눌려 졌을 때의 시간
      BackFirstClick: TDateTime;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

uses uBread;

{$R *.fmx}

// 빵 클래스를 쓰기 편하게...
procedure Bread(AOwner: TComponent; msg: string);
begin
    TBread.Create(AOwner, msg);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
    // 반드시 초기화... 그렇지 않으면 한 번만 눌러도 종료되는 현상이 가끔씩 나타남..
    HardwareBackClickCheckFlag := False;
end;

procedure TForm1.FormKeyUp(Sender: TObject; var Key: Word; var KeyChar: Char; Shift: TShiftState);
   // 지역 procedure
    procedure HardwareBackClickCheck;
    var
        BackSecondClick: TDateTime;
        BackClickTimeSpan: Int64;
    begin
        if not HardwareBackClickCheckFlag then
        begin
            BackFirstClick := Now;
            Bread(Self, '''뒤로'' 버튼을 한 번 더 누르면 종료합니다.');
            HardwareBackClickCheckFlag := True;
            Exit;
        end;

        if HardwareBackClickCheckFlag then
        begin
            BackSecondClick := Now;
            BackClickTimeSpan := MillisecondsBetween(BackFirstClick, BackSecondClick);
            // 1500 millisecond 즉, 1.5초 안에 또 한 번 누르면 종료...
            if BackClickTimeSpan <= 1500 then  
                Close;
            BackFirstClick := Now;
            Bread(Self, '''뒤로'' 버튼을 한 번 더 누르면 종료합니다.');
        end;
    end;
var
    Keyboard: IFMXVirtualKeyboardService;
begin
    if Key = vkHardwareBack then
    begin
        Key := 0;
        HardwareBackClickCheck;
    end;
end;


// 빵  클래스입니다...  (파일 첨부)
// 필요하면 입 맛에 맞게 수정해 사용하시길....
unit uBread;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, FMX.Graphics,
  FMX.Types, FMX.Forms, FMX.Objects;

type
  TBread = class(TRoundRect)
  private
    FText: TText;
    FTimer: TTimer;
    procedure Free;
  public
    constructor Create(AOwner: TComponent; msg: string); reintroduce;
    destructor Destroy; override;
    procedure OnBreadTimer(Sender: TObject);
end;

var
  FInterval: Integer = 1500;  // 메시지가 떠 있는 시간

implementation

{ TBread }

constructor TBread.Create(AOwner: TComponent; msg: string);
begin
    inherited Create(AOwner);

    // Round Rectangle draw
    Parent := AOwner as TFmxObject;
    Align := TAlignLayout.Center;
    Fill.Color := TAlphaColorRec.Firebrick; 
    Stroke.Color := TAlphaColorRec.Null;
    Stroke.Cap := TStrokeCap.Round;
    Height := (AOwner as TForm).Canvas.TextHeight(msg) + 20;  //  20은 여유분
    // 문자열 길이에 맞게 자동 조절..
    Width := (AOwner as TForm).Canvas.TextWidth(msg) + 30;    // 30은 여유분

    // Text display
    FText := TText.Create(Self);
    FText.Parent := Self;
    FText.Align := TAlignLayout.Contents;
    FText.TextSettings.Font.Family := '맑은 고딕';
    FText.TextSettings.Font.Style := FText.TextSettings.Font.Style + [TFontStyle.fsBold];
    FText.TextSettings.FontColor := TAlphaColorRec.White;
    FText.TextSettings.HorzAlign := TTextAlign.Center;
    FText.TextSettings.VertAlign := TTextAlign.Center;
    FText.TextSettings.WordWrap := False;
    FText.AutoSize := True;
    FText.Text := msg;

    // Timer set
    FTimer := TTimer.Create(Self);
    FTimer.Parent := Self;
    FTimer.Interval := FInterval;
    FTimer.Enabled := True;
    FTimer.OnTimer := OnBreadTimer;
end;

destructor TBread.Destroy;
begin

  inherited;
end;

procedure TBread.Free;
begin
    FText.DisposeOf;
    FTimer.DisposeOf;
    Self.DisposeOf;
end;

procedure TBread.OnBreadTimer(Sender: TObject);
begin
    FTimer.Enabled := False;
    Free;
end;

end.

끝...

blog.naver.com/seejune66